UPDATE 31.10.: Amazon Alexa - ioBroker Skill läuft aus ?

[TT-Tom]

@beowolf

Mit dem Befehl wird der Motor doch deaktiviert, oder habe ich das falsch verstanden?

[Beowolf]

@tt-tom

Stimmt, aber der Motor zeigt das aber so.

Der "Ursprungserzeuger" des Programms, nutzt inzwischen die Schrittmotoransteuerung durch die MobaTools. Er sagt, das die per Interrupt getaktet werden, was meist besser funktioniert.

Ich kenne die Tools aber nicht.

[Andreios]

@beowolf sagte in GPIO Status Wemos d1 mini an iobroker senden:

@tt-tom sagte in GPIO Status Wemos d1 mini an iobroker senden:

@Beowolf ist dir das schon mal aufgefallen das die Tür nach einem Neustart des WEMOS losgefahren ist?

Jepp. Schon gemerkt. Die Tür fährt zu.

Besser wäre es glaube ich, wenn die Tür nichts machen würde.

Zu der aktuellen Version.

Tastersteuerung geht fast.

1. Taste für AUFgedrückt - Tür fährt auf solange ich den Taster gedrückt halte - bis zum Endschalter - Tür hält an.

ABER

Wenn ich nun den Taster für ZU drücke möchte die Tür noch weiter auf fahren.

Auch bleibt die LED auf weiß wenn ich per Taster die Tür zu gefahren habe.

Das sind aber alles Dinge die im Normnalbetrieb glaube ich vollkommen egal sind.

@beowolf sagte in GPIO Status Wemos d1 mini an iobroker senden:

@tt-tom sagte in GPIO Status Wemos d1 mini an iobroker senden:

@Beowolf ist dir das schon mal aufgefallen das die Tür nach einem Neustart des WEMOS losgefahren ist?

Jepp. Schon gemerkt. Die Tür fährt zu.

Besser wäre es glaube ich, wenn die Tür nichts machen würde.

Was dabei zu prüfen wäre ist, ob der Motor beim Neueinschalten sein altes Ziel noch hat, dann müsste das im Setup zurückgesetzt werden, falls möglich.
Außerdem für den Startlauf die Merker z.B. -1 definieren und damit erst einmal nicht auf gesetzte Tasten reagieren (Flankenerkennung), so dass also selbst dann, wenn Du wirklich beim Einschalten des Wemos die Taste gedrückt hälst, das ignoriert wird.
Aktuell ist es so, dass, da der Merker auf 0 steht, wenn die Taste beim Start gedrückt ist, eine positive Flanke erkannt wird, der Motor läuft ggfs. los.
Ist der Merker beim Start auf -1 und die Flanke wird damit ignoriert, dann steht der Merker danach auf 1 und ab da läuft alles ganz normal, zuerst kommt die negative Flanke, wenn die Taste losgelassen wird und der Merker wird 0.

[TT-Tom]

@andreas-5 @Beowolf
Ich glaube, ich habe das jetzt mit der Stepper verstanden. Der Tip war MobaTools. Ich bin auch im Moba Verein und dort nutzen wir Servos zum Steuern der Weichen. Im Prinzip das selbe wie mit einem Stepper. Wir messen / testen bis wir die richtige Lage der Weiche erreicht haben, und speichern den Wert. Da gibt es keine Endlagenschalter und wenn sind sie nur zur Anzeige. Die Steuerung funktioniert alleine über die Wegstrecke / Schritte.

Soll heissen @Beowolf, du musst deine Schritte von Auf nach Zu noch einmal ausmessen, damit sie im Bereich der Endlagen anhält. Eine Abschaltung und "Reset" des Stepper bringt nix, im schlimmsten Fall verschiebt sich dadurch sein Fahrbereich, weil er immer die gesamten Schritte fahren will.

Ich hoffe ich habe mich gut ausgedrückt und ihr habt es verstanden.

Mit MQTT müsste auch über ein State bzw. Zeitstempel überwacht werden. Aber in der Materie bin ich noch nicht so fit.

Gruß Tom

[Beowolf]

@tt-tom sagte in GPIO Status Wemos d1 mini an iobroker senden:

du musst deine Schritte von Auf nach Zu noch einmal ausmessen,

Das war auch so geplant. Bis jetzt war es nur so, das ich sicher sein wollte, das die Endlage der Tür durch die Endschalter definiert wird. Es gehen schon mal Schritte verloren. Deshalb das "zu viel" an Schritten.

Ich h offe auch, das dieses ganze gefummel mit den Taster ganz selten gebraucht wird. Per ioBroker morgens Tür auf - abends wieder zu - fertig. Nur die Zeiten verschieben sich.

[TT-Tom]

@beowolf

habe nochmal mit den Einstellungen vom MQTT Adapter gespielt. Bei folgenden Einstellungen ist die Tür bei mir nicht mehr gefahren, weder beim Neustart des Adapter noch beim Neustart des WEMOS.

"Eigene States beim Verbinden publizieren" und "States bei subscribe publizieren" habe ich beide deaktiviert.

ich weiß jetzt nicht ob du noch andere Projekte hast die diese Einstellung benötigen.

[Beowolf]

@tt-tom
Jepp - geht.

Muß ich mal beobachten ob andere Dinge jetzt Probleme haben.

[Beowolf]

Ich habe da noch eine Frage.

Ich muß noch den Schaltzustand von einem Pegelschalter (Wasserstand) an ioBroker gesendet bekommen.

Es sollte so sein, das der Schalter beim "Neustart" des Wemos d1 mini einmalig abgefragt wird, den Zustand nach ioBroker sendet, und dann erst z.B. in einem Intervall von einer Stunde wieder.

Was ich bis jetzt habe:

Unter void loop

  Pegelstand_lesen();

Dann bei

void Pegelstand_lesen() {
    if (digitalRead(Pegelschalter)) {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "1");
          } else {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "0");
      }
}

Im LOG Fenster kommt ununterbrochen die "Statusmeldung" des Pegelschalters ein. Das kann so nicht richtig sein.

Grüße
Manfred

[TT-Tom]

@beowolf sagte Im LOG Fenster kommt ununterbrochen die "Statusmeldung" des Pegelschalters ein. Das kann so nicht richtig sein.

doch, den unter void Loop läuft deine Programmschleife. das heist bei jedem Durchlauf werden alle Sachen dort ausgeführt. In deinem Fall "Pegelstand_lesen();"

du musst eine Pause einsetzen

[Beowolf]

@tt-tom

mit

delay(3600);

So?

[TT-Tom]

@beowolf

ja zum Beispiel, machst du noch mehr Sachen mit dem Wemos?

Edit das sind Millisekunden

[Beowolf]

@tt-tom
Ja, damit wird noch ein Ventil gesteuert?

[TT-Tom]

@beowolf dann zeige mal das ganze Programm bitte. Möchte gerne mal rüber schauen.

[Beowolf]

@tt-tom

#include <ESP8266WiFi.h>
#include <ArduinoOTA.h>
#include <PubSubClient.h>
#include <AccelStepper.h>
#include <Adafruit_NeoPixel.h>

#ifndef STASSID
#define STASSID "----"
#define STAPSK  "------"
#endif

#define MotorStatus D2 // Steppermotor aktivieren/deaktivieren
#define LEDpin D7 // Umgesteuerter GPIO für die NEO-Led
#define NUMPIXELS 1 // Anzal der LEDs

const char* ssid = STASSID;
const char* password = STAPSK;

char* mqtt_client_id = "Essig_Aussen";
const char* mqtt_server = "192.168.---";
const int mqtt_port = 1886;
const char* mqtt_user = "----";
const char* mqtt_password = "------";

const byte Pegelschalter = D6;    // Pegelschalter für Essigvorrat
const byte RelaisVentil = D5;   // Relais für Wasserzufuhrventil

const long SchritteUmdrehung = 200; // Schritte des Schrittmotors für 360 Grad der Tür
const unsigned int TuerbewegungZu =  61000;
const unsigned int TuerbewegungAuf = -61000;

int lebenszeichen_zaehler = 0; // Zähler um Lebenzeichen an MQTT Broker zusenden
int lebenszeichen_interval = 10; // interval für MQTT Broker in sek

long led_takt    = 500; // Zeittakt (ms) für die LED  ##takt##
long led_zeit; // Letzter Durchlauf (ms) für die LED  ##takt##
long lebenszeichen_takt = lebenszeichen_interval * 1000; // Zeittakt (ms)  ##takt##
long lebenszeichen_zeit; // Letzter Durchlauf (ms)  ##takt##
long lebenszeichen_ein_aus = 0; // ##takt##

WiFiClient espClient;
PubSubClient mqttClient(espClient);

AccelStepper stepper(1, D3, D4);  //Pins für den Steppermotor STEP , DIR
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(1, LEDpin, NEO_GRB + NEO_KHZ800);

void setup() {

  pinMode(LEDpin, OUTPUT); // NEO-LED
  pinMode(Pegelschalter, INPUT_PULLUP);    // Pegelschalter für Essigtank
  pinMode(RelaisVentil, OUTPUT);   // Relais für Wasserzufuhrventil
  pinMode(MotorStatus, OUTPUT); // Enable Motor 1
  pinMode(LED_BUILTIN, OUTPUT); // Board-LED nutzen
  stepper.setMaxSpeed(1000);
  stepper.setAcceleration(1500);

  Serial.begin(9600);
  //  while(!Serial){
  //    ; // wartet bis die serielle Schnittstelle eine Verbindung hergestellt hat. Wird für natives USB benötigt
  //  }

  // Per WLAN mit dem Netzwerk verbinden
  Serial.print("Verbinden mit ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  ///////////////////////////////////////////
  // Anfang Update über Wlan
  ///////////////////////////////////////////

  ArduinoOTA.onStart([]() {
    String type;
    if (ArduinoOTA.getCommand() == U_FLASH) {
      type = "sketch";
    } else { // U_FS
      type = "filesystem";
    }

    // NOTE: if updating FS this would be the place to unmount FS using FS.end()
    Serial.println("Start updating " + type);
  });
  ArduinoOTA.onEnd([]() {
    Serial.println("\nEnd");
  });
  ArduinoOTA.onProgress([](unsigned int progress, unsigned int total) {
    Serial.printf("Progress: %u%%\r", (progress / (total / 100)));
  });
  ArduinoOTA.onError([](ota_error_t error) {
    Serial.printf("Error[%u]: ", error);
    if (error == OTA_AUTH_ERROR) {
      Serial.println("Auth Failed");
    } else if (error == OTA_BEGIN_ERROR) {
      Serial.println("Begin Failed");
    } else if (error == OTA_CONNECT_ERROR) {
      Serial.println("Connect Failed");
    } else if (error == OTA_RECEIVE_ERROR) {
      Serial.println("Receive Failed");
    } else if (error == OTA_END_ERROR) {
      Serial.println("End Failed");
    }
  });
  ArduinoOTA.begin();

  ///////////////////////////////////////////
  // Ende Update über Wlan
  ///////////////////////////////////////////

  // Die IP vom Webserver auf dem seriellen Monitor ausgeben
  Serial.println("");
  Serial.println("WLAN verbunden.");
  Serial.println("IP Adresse: ");
  Serial.println(WiFi.localIP());

  // MQTT Brocker
  // Mit ioBroker Mqtt verbinden
  mqttClient.setServer(mqtt_server, mqtt_port);//MQTT Server, - Port
  mqttClient.setCallback(callback);

  // NEO_Pixel Start
  pixels.begin(); // This initializes the NeoPixel library.

  lebenszeichen_zeit = millis(); // ##takt##
  led_zeit = millis(); // ##takt##

  Serial.println("Programmanfang");
}

//ende Setup
//////////////////////////////////////////////////////////////////////////////////

void loop() {


  Pegelstand_lesen();
  lebenszeichen();

  ArduinoOTA.handle();
  ArduinoOTA.setHostname("Essig_Aussen");

  stepper.run();

  // MQTT Broker
  mqttClient.loop();
  if (!mqttClient.connected()) {
    reconnectToMQTT();
  }

}

//ende loop
/////////////////////////////////////////////////////////////////////////////////

void Pegelstand_lesen() {
    if (digitalRead(Pegelschalter)) {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "1");
          } else {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "0");
      delay(1000000);
      }
}




// MQTT Funktion
// *************
void reconnectToMQTT() {

  if (mqttClient.connect(mqtt_client_id , mqtt_user, mqtt_password)) {
    Serial.println("Per MQTT mit ioBroker verbunden");

//    mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", (digitalRead(Pegelschalter)));
    mqttClient.publish("HH_Frischwasser/Innen/alive", "0");


    mqttClient.subscribe("HH_Frischwasser/Innen/Frischwasserventil");
  } else {
    Serial.print("mqtt-Verbindung fehlgeschlagen ");
    Serial.print(mqttClient.state());
    Serial.println(" versuchen es in 5 Sekunden erneut");
    // Wait 5 seconds before retrying
    delay(5000);
  }
}


// MQTT Callback
void callback(char* topic, byte* payload, unsigned int length)
{

  payload[length] = '\0';
  String strTopic = String(topic);
  String strPayload = String((char * ) payload);

  Serial.print("Nachricht angekommen [");
  Serial.print(strTopic);
  Serial.print("----");
  Serial.print(strPayload);
  Serial.print("] ");
  Serial.println();


  if (strTopic == "HH_Frischwasser/Innen/Frischwasserventil")
  {
    // Pumpe Start
    if (strPayload == "false") {
      Serial.println("Pumpenstart über IoBroker");
      digitalWrite(RelaisVentil, HIGH);
    }

    // Pumpe Stop
    if (strPayload == "true") {
      Serial.println("Pumpenstop über IoBroker");
      digitalWrite(RelaisVentil, LOW);
    }
  }
}

void lebenszeichen() {
  
  // ##takt## --> 
  long current_time = millis();
  // LED auf dem Board blinken lassen
  if (led_zeit <= current_time) {
    if (digitalRead(LED_BUILTIN) == HIGH)
      digitalWrite(LED_BUILTIN, LOW);
    else
      digitalWrite(LED_BUILTIN, HIGH);
    while (led_zeit <= current_time)
      led_zeit += led_takt;
  }
  
  if (lebenszeichen_zeit <= current_time) {
    if (lebenszeichen_ein_aus == 0) {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "1");
      lebenszeichen_ein_aus = 1;
    } else {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "0");
      lebenszeichen_ein_aus = 0;
    }
    while (lebenszeichen_zeit <= current_time)
      lebenszeichen_zeit += lebenszeichen_takt;
  }
  // ##takt## <-- 
}

Das meiste ist von Deinem Programm, bzw. ich habe für diesen Zweck einiges entfernt.

Ist noch nicht fertig.

[Beowolf]

Kurze Beschreibung was das Programm später machen soll?

Ein Pegelschalter in einem Wasservorrat meldet an ioBroker - "Wasser ist alle".

So - jetzt läuft eine kleine Routine unter ioBroker.

ioBroker sendet an diesen Wemos mit dem kleinen Programm hier:

1. Mache ein Ventil auf
2. Starte einen Schrittmotor (der Programmteil ist noch nicht eingebaut) für ca. 10 Sekunden.
3. Mache das Ventil wieder zu

Mehr passiert hier nicht.

[TT-Tom]

@beowolf

was macht die Routine genau? vielleicht können wir das in den Wemos mit reinpacken.

okay das müssen wir erstmal aufräumen, lass mir mal bis morgen Zeit. Muss noch nachher zum Dienst. Melde mich morgen wieder.

[Beowolf]

@tt-tom

Die macht nicht weiteres als

Wenn Wasser alle - Setzte Ventil auf "true" und starte den Schrittmotor für 10 sek.

An dem Wassertank ist für "Voll" natürlich noch ein Pegelschalter.

Wenn der schaltet gibt er natürlich das auch an ioBroker weiter, und in der "Routine" steht dann, "schliesse Ventil.

Das da ioBroker zwischen sitzt ist nicht schlimm. Im Wassertank selber ist noch ein Schwimmerventil. Das bedeutet, sollte ioBroker nicht laufen, oder das Wlan nicht funktioniert, stellt das Schwimmerventil manuell und mechanisch den Wasserzufluß ab. Ich wollte nur nicht, das die Zuleitungen zum Wassertank ständig und Druck sind. Wenn das Ventil vor dem Schwimmerschalter schließt, ist nur ein kleiner Teil der Leitungen unter Druck.

[TT-Tom]

@beowolf
mit dem Delay bleibt das Programm stehen, heist für 10sek. Wenn es so gelöst wird wie beim Lebenszeichen, gibt es keine Stillstände.

  if (lebenszeichen_zeit <= current_time) {
    if (lebenszeichen_ein_aus == 0) {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "1");
      lebenszeichen_ein_aus = 1;
    } else {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "0");
      lebenszeichen_ein_aus = 0;
    }
    while (lebenszeichen_zeit <= current_time)
      lebenszeichen_zeit += lebenszeichen_takt;
  }

[TT-Tom]

@Beowolf

probiere mal aus, er sollte jetzt alle 10 sek den Pegelschalter prüfen.

#include <ESP8266WiFi.h>
#include <ArduinoOTA.h>
#include <PubSubClient.h>
#include <AccelStepper.h>
#include <Adafruit_NeoPixel.h>

#ifndef STASSID
#define STASSID "----"
#define STAPSK  "------"
#endif

#define MotorStatus D2 // Steppermotor aktivieren/deaktivieren
#define LEDpin D7 // Umgesteuerter GPIO für die NEO-Led
#define NUMPIXELS 1 // Anzal der LEDs

const char* ssid = STASSID;
const char* password = STAPSK;

char* mqtt_client_id = "Essig_Aussen";
const char* mqtt_server = "192.168.---";
const int mqtt_port = 1886;
const char* mqtt_user = "----";
const char* mqtt_password = "------";

const byte Pegelschalter = D6;    // Pegelschalter für Essigvorrat
const byte RelaisVentil = D5;   // Relais für Wasserzufuhrventil

const long SchritteUmdrehung = 200; // Schritte des Schrittmotors für 360 Grad der Tür
const unsigned int TuerbewegungZu =  61000;
const unsigned int TuerbewegungAuf = -61000;

int lebenszeichen_zaehler = 0; // Zähler um Lebenzeichen an MQTT Broker zusenden
int lebenszeichen_interval = 10; // interval für MQTT Broker in sek
int messung_interval = 10; // interval für Pegelmessung in sek

long led_takt    = 500; // Zeittakt (ms) für die LED  ##takt##
long led_zeit; // Letzter Durchlauf (ms) für die LED  ##takt##
long lebenszeichen_takt = lebenszeichen_interval * 1000; // Zeittakt (ms)  ##takt##
long lebenszeichen_zeit; // Letzter Durchlauf (ms)  ##takt##
long lebenszeichen_ein_aus = 0; // ##takt##

long messung_takt = messung_interval *1000; // Zeittakt (ms)
long messung_zeit;  //Letzter Durchlauf (ms)


WiFiClient espClient;
PubSubClient mqttClient(espClient);

AccelStepper stepper(1, D3, D4);  //Pins für den Steppermotor STEP , DIR
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(1, LEDpin, NEO_GRB + NEO_KHZ800);

void setup() {

  pinMode(LEDpin, OUTPUT); // NEO-LED
  pinMode(Pegelschalter, INPUT_PULLUP);    // Pegelschalter für Essigtank
  pinMode(RelaisVentil, OUTPUT);   // Relais für Wasserzufuhrventil
  pinMode(MotorStatus, OUTPUT); // Enable Motor 1
  pinMode(LED_BUILTIN, OUTPUT); // Board-LED nutzen
  stepper.setMaxSpeed(1000);
  stepper.setAcceleration(1500);

  Serial.begin(9600);
  //  while(!Serial){
  //    ; // wartet bis die serielle Schnittstelle eine Verbindung hergestellt hat. Wird für natives USB benötigt
  //  }

  // Per WLAN mit dem Netzwerk verbinden
  Serial.print("Verbinden mit ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  ///////////////////////////////////////////
  // Anfang Update über Wlan
  ///////////////////////////////////////////

  ArduinoOTA.onStart([]() {
    String type;
    if (ArduinoOTA.getCommand() == U_FLASH) {
      type = "sketch";
    } else { // U_FS
      type = "filesystem";
    }

    // NOTE: if updating FS this would be the place to unmount FS using FS.end()
    Serial.println("Start updating " + type);
  });
  ArduinoOTA.onEnd([]() {
    Serial.println("\nEnd");
  });
  ArduinoOTA.onProgress([](unsigned int progress, unsigned int total) {
    Serial.printf("Progress: %u%%\r", (progress / (total / 100)));
  });
  ArduinoOTA.onError([](ota_error_t error) {
    Serial.printf("Error[%u]: ", error);
    if (error == OTA_AUTH_ERROR) {
      Serial.println("Auth Failed");
    } else if (error == OTA_BEGIN_ERROR) {
      Serial.println("Begin Failed");
    } else if (error == OTA_CONNECT_ERROR) {
      Serial.println("Connect Failed");
    } else if (error == OTA_RECEIVE_ERROR) {
      Serial.println("Receive Failed");
    } else if (error == OTA_END_ERROR) {
      Serial.println("End Failed");
    }
  });
  ArduinoOTA.begin();

  ///////////////////////////////////////////
  // Ende Update über Wlan
  ///////////////////////////////////////////

  // Die IP vom Webserver auf dem seriellen Monitor ausgeben
  Serial.println("");
  Serial.println("WLAN verbunden.");
  Serial.println("IP Adresse: ");
  Serial.println(WiFi.localIP());

  // MQTT Brocker
  // Mit ioBroker Mqtt verbinden
  mqttClient.setServer(mqtt_server, mqtt_port);//MQTT Server, - Port
  mqttClient.setCallback(callback);

  // NEO_Pixel Start
  pixels.begin(); // This initializes the NeoPixel library.

  lebenszeichen_zeit = millis(); // ##takt##
  led_zeit = millis(); // ##takt##
  messung_zeit = millis();

  Serial.println("Programmanfang");
}

//ende Setup
//////////////////////////////////////////////////////////////////////////////////

void loop() {


  Pegelstand_lesen();
  lebenszeichen();

  ArduinoOTA.handle();
  ArduinoOTA.setHostname("Essig_Aussen");

  stepper.run();

  // MQTT Broker
  mqttClient.loop();
  if (!mqttClient.connected()) {
    reconnectToMQTT();
  }

}

//ende loop
/////////////////////////////////////////////////////////////////////////////////

void Pegelstand_lesen() {
   long current_time = millis();

  if (messung_zeit <= current_time) {
    if (digitalRead(Pegelschalter)) {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "1");
          } else {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "0");
      }
    while (messung_zeit <= current_time)
      messung_zeit += messung_takt;
  }
}




// MQTT Funktion
// *************
void reconnectToMQTT() {

  if (mqttClient.connect(mqtt_client_id , mqtt_user, mqtt_password)) {
    Serial.println("Per MQTT mit ioBroker verbunden");

//    mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", (digitalRead(Pegelschalter)));
    mqttClient.publish("HH_Frischwasser/Innen/alive", "0");


    mqttClient.subscribe("HH_Frischwasser/Innen/Frischwasserventil");
  } else {
    Serial.print("mqtt-Verbindung fehlgeschlagen ");
    Serial.print(mqttClient.state());
    Serial.println(" versuchen es in 5 Sekunden erneut");
    // Wait 5 seconds before retrying
    delay(5000);
  }
}


// MQTT Callback
void callback(char* topic, byte* payload, unsigned int length)
{

  payload[length] = '\0';
  String strTopic = String(topic);
  String strPayload = String((char * ) payload);

  Serial.print("Nachricht angekommen [");
  Serial.print(strTopic);
  Serial.print("----");
  Serial.print(strPayload);
  Serial.print("] ");
  Serial.println();


  if (strTopic == "HH_Frischwasser/Innen/Frischwasserventil")
  {
    // Pumpe Start
    if (strPayload == "false") {
      Serial.println("Pumpenstart über IoBroker");
      digitalWrite(RelaisVentil, HIGH);
    }

    // Pumpe Stop
    if (strPayload == "true") {
      Serial.println("Pumpenstop über IoBroker");
      digitalWrite(RelaisVentil, LOW);
    }
  }
}

void lebenszeichen() {
  
  // ##takt## --> 
  long current_time = millis();
  // LED auf dem Board blinken lassen
  if (led_zeit <= current_time) {
    if (digitalRead(LED_BUILTIN) == HIGH)
      digitalWrite(LED_BUILTIN, LOW);
    else
      digitalWrite(LED_BUILTIN, HIGH);
    while (led_zeit <= current_time)
      led_zeit += led_takt;
  }
  
  if (lebenszeichen_zeit <= current_time) {
    if (lebenszeichen_ein_aus == 0) {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "1");
      lebenszeichen_ein_aus = 1;
    } else {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "0");
      lebenszeichen_ein_aus = 0;
    }
    while (lebenszeichen_zeit <= current_time)
      lebenszeichen_zeit += lebenszeichen_takt;
  }
  // ##takt## <-- 
}

[Beowolf]

@tt-tom

Jepp. Funktioniert. Vielen Dank dafür.