GPIO Status Wemos d1 mini an iobroker senden

TT-Tom

den Aufruf von stop würde ich noch nicht setzen. der Motor sollte nach den Schritten selber stehen bleiben. ggf. versuche mal statt stepper.run(), stepper.stop()

 if (strTopic == "HH_Frischwasser/Innen/Essigdosierer")
  {
    // Essigdosierer Start
    if (strPayload == "true") {
      Serial.println("Start Essigdosierer über IoBroker");
      digitalWrite(MotorStatus, LOW);  //Motor aktiviert

      stepper.move(Essigdosis); // move -> relativ zur aktuellen position
      stepper.run();
      mqttClient.publish("HH_Frischwasser/Innen/Essigdosierer", "false");

Beowolf

@tt-tom

Nö, tut nich.

Der Motor läuft nicht an. Er ist nur "angeschaltet" sprich, man kann ihn nicht mauell drehen.

Bin jetzt auch erst wech. Vielen Dank für die Hilfe bis hier hin.

TT-Tom

@beowolf
sende mir mal bitte dein aktuellen Code. ich möchte ihn mal vergleichen mit der Hühnertür. Dort haben wir ja nur mit move gearbeitet und es hat funktioniert.

TT-Tom

@Beowolf

versuche bitte mal diesen Code, ist ähnlich der Hühnertür.

// MQTT Callback
void callback(char* topic, byte* payload, unsigned int length)
{

  payload[length] = '\0';
  String strTopic = String(topic);
  String strPayload = String((char * ) payload);

  Serial.print("Nachricht angekommen [");
  Serial.print(strTopic);
  Serial.print("----");
  Serial.print(strPayload);
  Serial.print("] ");
  Serial.println();


  if (strTopic == "HH_Frischwasser/Innen/Frischwasserventil")
  {
    // Pumpe Start
    if (strPayload == "false") {
      Serial.println("Pumpenstart über IoBroker");
      digitalWrite(RelaisVentil, HIGH);
    }

    // Pumpe Stop
    if (strPayload == "true") {
      Serial.println("Pumpenstop über IoBroker");
      digitalWrite(RelaisVentil, LOW);
    }
  }

  
  if (strTopic == "HH_Frischwasser/Innen/Essigdosierer")
  {
    // Essigdosierer Start
    if (strPayload == "true") {
      Serial.println("Start Essigdosierer über IoBroker");
      digitalWrite(MotorStatus, LOW);  //Motor aktiviert
      stepper.move(Essigdosis);
      mqttClient.publish("HH_Frischwasser/Innen/Essigdosierer", "false");
    }
  }
}

Beowolf

@tt-tom
Hier mien Code

#include <ESP8266WiFi.h>
#include <ArduinoOTA.h>
#include <PubSubClient.h>
#include <AccelStepper.h>
#include <Adafruit_NeoPixel.h>

#ifndef STASSID
#define STASSID "----"
#define STAPSK  "----"
#endif

#define MotorStatus D2 // Steppermotor aktivieren/deaktivieren
#define LEDpin D7 // Umgesteuerter GPIO für die NEO-Led
#define NUMPIXELS 1 // Anzal der LEDs

const char* ssid = STASSID;
const char* password = STAPSK;

char* mqtt_client_id = "Essig_Innen";
const char* mqtt_server = "192.-----
const int mqtt_port = 1886;
const char* mqtt_user = "--";
const char* mqtt_password = "--";

const byte Pegelschalter = D6;    // Pegelschalter für Essigvorrat
const byte RelaisVentil = D5;   // Relais für Wasserzufuhrventil

const long SchritteUmdrehung = 200; // Schritte des Schrittmotors für 360 Grad der Tür
const unsigned int Essigdosis =  10000;


int lebenszeichen_zaehler = 0; // Zähler um Lebenzeichen an MQTT Broker zusenden
int lebenszeichen_interval = 10; // interval für MQTT Broker in sek
int messung_interval = 10; // interval für Pegelmessung in sek

long led_takt    = 500; // Zeittakt (ms) für die LED  ##takt##
long led_zeit; // Letzter Durchlauf (ms) für die LED  ##takt##
long lebenszeichen_takt = lebenszeichen_interval * 1000; // Zeittakt (ms)  ##takt##
long lebenszeichen_zeit; // Letzter Durchlauf (ms)  ##takt##
long lebenszeichen_ein_aus = 0; // ##takt##

long messung_takt = messung_interval *1000; // Zeittakt (ms)
long messung_zeit;  //Letzter Durchlauf (ms)


WiFiClient espClient;
PubSubClient mqttClient(espClient);

AccelStepper stepper(1, D3, D4);  //Pins für den Steppermotor STEP , DIR
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(1, LEDpin, NEO_GRB + NEO_KHZ800);

void setup() {

  pinMode(LEDpin, OUTPUT); // NEO-LED
  pinMode(Pegelschalter, INPUT_PULLUP);    // Pegelschalter für Essigtank
  pinMode(RelaisVentil, OUTPUT);   // Relais für Wasserzufuhrventil
  pinMode(MotorStatus, OUTPUT); // Enable Motor 1
  pinMode(LED_BUILTIN, OUTPUT); // Board-LED nutzen
  stepper.setMaxSpeed(1000);
  stepper.setAcceleration(1500);

  digitalWrite(MotorStatus, HIGH); //Motor deaktiviert

  Serial.begin(9600);
  //  while(!Serial){
  //    ; // wartet bis die serielle Schnittstelle eine Verbindung hergestellt hat. Wird für natives USB benötigt
  //  }

  // Per WLAN mit dem Netzwerk verbinden
  Serial.print("Verbinden mit ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  ///////////////////////////////////////////
  // Anfang Update über Wlan
  ///////////////////////////////////////////

  ArduinoOTA.onStart([]() {
    String type;
    if (ArduinoOTA.getCommand() == U_FLASH) {
      type = "sketch";
    } else { // U_FS
      type = "filesystem";
    }

    // NOTE: if updating FS this would be the place to unmount FS using FS.end()
    Serial.println("Start updating " + type);
  });
  ArduinoOTA.onEnd([]() {
    Serial.println("\nEnd");
  });
  ArduinoOTA.onProgress([](unsigned int progress, unsigned int total) {
    Serial.printf("Progress: %u%%\r", (progress / (total / 100)));
  });
  ArduinoOTA.onError([](ota_error_t error) {
    Serial.printf("Error[%u]: ", error);
    if (error == OTA_AUTH_ERROR) {
      Serial.println("Auth Failed");
    } else if (error == OTA_BEGIN_ERROR) {
      Serial.println("Begin Failed");
    } else if (error == OTA_CONNECT_ERROR) {
      Serial.println("Connect Failed");
    } else if (error == OTA_RECEIVE_ERROR) {
      Serial.println("Receive Failed");
    } else if (error == OTA_END_ERROR) {
      Serial.println("End Failed");
    }
  });
  ArduinoOTA.begin();

  ///////////////////////////////////////////
  // Ende Update über Wlan
  ///////////////////////////////////////////

  // Die IP vom Webserver auf dem seriellen Monitor ausgeben
  Serial.println("");
  Serial.println("WLAN verbunden.");
  Serial.println("IP Adresse: ");
  Serial.println(WiFi.localIP());

  // MQTT Brocker
  // Mit ioBroker Mqtt verbinden
  mqttClient.setServer(mqtt_server, mqtt_port);//MQTT Server, - Port
  mqttClient.setCallback(callback);

  // NEO_Pixel Start
  pixels.begin(); // This initializes the NeoPixel library.

  lebenszeichen_zeit = millis(); // ##takt##
  led_zeit = millis(); // ##takt##
  messung_zeit = millis();

  Serial.println("Programmanfang");
}

//ende Setup
//////////////////////////////////////////////////////////////////////////////////

void loop() {


  Pegelstand_lesen();
  lebenszeichen();

  ArduinoOTA.handle();
  ArduinoOTA.setHostname("Essig_Innen");

//  stepper.run();

  // MQTT Broker
  mqttClient.loop();
  if (!mqttClient.connected()) {
    reconnectToMQTT();
  }

}

//ende loop
/////////////////////////////////////////////////////////////////////////////////

void Pegelstand_lesen() {
   long current_time = millis();

  if (messung_zeit <= current_time) {
    if (digitalRead(Pegelschalter)) {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "1");
          } else {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "0");
      }
    while (messung_zeit <= current_time)
      messung_zeit += messung_takt;
  }
}

// MQTT Funktion
// *************
void reconnectToMQTT() {

  if (mqttClient.connect(mqtt_client_id , mqtt_user, mqtt_password)) {
    Serial.println("Per MQTT mit ioBroker verbunden");

    mqttClient.publish("HH_Frischwasser/Innen/alive", "0");


    mqttClient.subscribe("HH_Frischwasser/Innen/Frischwasserventil");
    mqttClient.subscribe("HH_Frischwasser/Innen/Essigdosierer");
  } else {
    Serial.print("mqtt-Verbindung fehlgeschlagen ");
    Serial.print(mqttClient.state());
    Serial.println(" versuchen es in 5 Sekunden erneut");
    // Wait 5 seconds before retrying
    delay(5000);
  }
}


// MQTT Callback
void callback(char* topic, byte* payload, unsigned int length)
{

  payload[length] = '\0';
  String strTopic = String(topic);
  String strPayload = String((char * ) payload);

  Serial.print("Nachricht angekommen [");
  Serial.print(strTopic);
  Serial.print("----");
  Serial.print(strPayload);
  Serial.print("] ");
  Serial.println();


  if (strTopic == "HH_Frischwasser/Innen/Frischwasserventil")
  {
    // Pumpe Start
    if (strPayload == "false") {
      Serial.println("Pumpenstart über IoBroker");
      digitalWrite(RelaisVentil, HIGH);
    }

    // Pumpe Stop
    if (strPayload == "true") {
      Serial.println("Pumpenstop über IoBroker");
      digitalWrite(RelaisVentil, LOW);
    }
  }


  if (strTopic == "HH_Frischwasser/Innen/Essigdosierer")
  {
    // Essigdosierer Start
    if (strPayload == "true") {
      Serial.println("Start Essigdosierer über IoBroker");
      digitalWrite(MotorStatus, LOW);  //Motor aktiviert

      stepper.moveTo(Essigdosis);
//    while (stepper.currentPosition() != 1) // Full speed up to 300
      stepper.run();
      stepper.runToNewPosition(Essigdosis); // Cause an overshoot then back to 0
      mqttClient.publish("HH_Frischwasser/Innen/Essigdosierer", "false");
      stopp();
    }
  }
}

void stopp() {
  stepper.setCurrentPosition(0);
  stepper.stop();
  digitalWrite(MotorStatus, HIGH); //Motor deaktiviert
}

void lebenszeichen() {
  
  // ##takt## --> 
  long current_time = millis();
  // LED auf dem Board blinken lassen
  if (led_zeit <= current_time) {
    if (digitalRead(LED_BUILTIN) == HIGH)
      digitalWrite(LED_BUILTIN, LOW);
    else
      digitalWrite(LED_BUILTIN, HIGH);
    while (led_zeit <= current_time)
      led_zeit += led_takt;
  }
  
  if (lebenszeichen_zeit <= current_time) {
    if (lebenszeichen_ein_aus == 0) {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "1");
      lebenszeichen_ein_aus = 1;
    } else {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "0");
      lebenszeichen_ein_aus = 0;
    }
    while (lebenszeichen_zeit <= current_time)
      lebenszeichen_zeit += lebenszeichen_takt;
  }
  // ##takt## <-- 
}

TT-Tom

@beowolf
danke da ist dieses Zeichen {1} drin. Ist das in deinem Code auch? ersetze mal meinen Vorschlag und lass das STOP mal weg.

Beowolf

@tt-tom

Habe DeinenVorschlag eingesetzt. Motor läuft nicht.

// MQTT Callback
void callback(char* topic, byte* payload, unsigned int length)
{

  payload[length] = '\0';
  String strTopic = String(topic);
  String strPayload = String((char * ) payload);

  Serial.print("Nachricht angekommen [");
  Serial.print(strTopic);
  Serial.print("----");
  Serial.print(strPayload);
  Serial.print("] ");
  Serial.println();


  if (strTopic == "HH_Frischwasser/Innen/Frischwasserventil")
  {
    // Pumpe Start
    if (strPayload == "false") {
      Serial.println("Pumpenstart über IoBroker");
      digitalWrite(RelaisVentil, HIGH);
    }

    // Pumpe Stop
    if (strPayload == "true") {
      Serial.println("Pumpenstop über IoBroker");
      digitalWrite(RelaisVentil, LOW);
    }
  }

  
  if (strTopic == "HH_Frischwasser/Innen/Essigdosierer")
  {
    // Essigdosierer Start
    if (strPayload == "true") {
      Serial.println("Start Essigdosierer über IoBroker");
      digitalWrite(MotorStatus, LOW);  //Motor aktiviert
      stepper.move(Essigdosis);
      mqttClient.publish("HH_Frischwasser/Innen/Essigdosierer", "false");
    }
  }
}

//void stopp() {
//  stepper.setCurrentPosition(0);
//  stepper.stop();
//  digitalWrite(MotorStatus, HIGH); //Motor deaktiviert
//}

void lebenszeichen() {
  
  // ##takt## --> 
  long current_time = millis();
  // LED auf dem Board blinken lassen
  if (led_zeit <= current_time) {
    if (digitalRead(LED_BUILTIN) == HIGH)
      digitalWrite(LED_BUILTIN, LOW);
    else
      digitalWrite(LED_BUILTIN, HIGH);
    while (led_zeit <= current_time)
      led_zeit += led_takt;
  }
  
  if (lebenszeichen_zeit <= current_time) {
    if (lebenszeichen_ein_aus == 0) {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "1");
      lebenszeichen_ein_aus = 1;
    } else {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "0");
      lebenszeichen_ein_aus = 0;
    }
    while (lebenszeichen_zeit <= current_time)
      lebenszeichen_zeit += lebenszeichen_takt;
  }
  // ##takt## <-- 
}

Beowolf

@tt-tom sagte in GPIO Status Wemos d1 mini an iobroker senden:

@beowolf
danke da ist dieses Zeichen {1} drin.

Nein, ist nicht drin. Ist wohl durch das kopieren passiert.

TT-Tom

@beowolf läuft den dein Ursprung Script noch? langsam bin ich am zweifeln wo der Fehler ist.

Beowolf

@tt-tom

Jepp, der läuft.

Bei Deiner Änderung wird nur der Motor "eingeschaltet" aber läuft nicht. Hält als "fest".

TT-Tom

@beowolf sagte in GPIO Status Wemos d1 mini an iobroker senden:

@tt-tom

Jepp, der läuft.

aber der wird der Chip blockiert bis der Motor fertig ist.

Beowolf

Das das Skript durch den Befehl in dem Moment geblockt wird ist nicht wirklich schlimm.

Die Dosierpumpe läuft ca. 6 - 8 Sekunden. Das Befüllen des Wassertanks dauert ca. 40 - 50 Sekunden. Das also das Signal des "Pegelvoll-Schalters" nicht verarbeitet wird, ist sehr unwahrscheinlich.

Eine andere Möglichkeit sehe ich im Moment nicht. So wie mein Skript ist, kann ich wenigsten sehen, wann der Dosierer fertig ist.

TT-Tom

@Beowolf
ja okay, dann musst du damit erstmal arbeiten. hast du eine LED mit dran? wenn nein könnte das raus. Ich werde mal die Beschreibung nochmal durchlesen und neu ansetzen.

Melde mich dann wieder.

Beowolf

@tt-tom

LEDs bin ich mir noch nicht sicher. Ein wenig blink-blink ist doch immer schön. :blush:

TT-Tom

@beowolf okay das bekommen wir hin :)

TT-Tom

@beowolf

ich habe einen Fehler gefunden. Kannst du bitte mal nachsehen, im letzten Code den du mir gesendet hast ist im LOOP - Teil "stepper.run();" aus kommentiert, dass darf nicht sein. Das bitte aktivieren und dann mein Vorschlag im Mqtt-Teil einbinden.

Beowolf

@tt-tom

Jepp, jetzt dreht der Motor. Hatte ich übersehen, das ich das auskommentiert hatte.

ABER.

Der Motor wird nicht wieder deaktiviert. Das ist nicht so schön.

Beowolf

@tt-tom

Ich habe jetzt das:

      // Essigdosierer Stopp
    if (stepper.currentPosition() == Essigdosis) {
      Serial.println(stepper.currentPosition());
      mqttClient.publish("HH_Frischwasser/Innen/Essigdosierer", "false");      
      Serial.println("Essigdosierer gestoppt");      
      stopp();
    }

in void loop() eingebaut.

Also so:

//////////////////////////////////////////////////////////////////////////////////
 
void loop() {
 
 
  Pegelstand_lesen();
  lebenszeichen();
 
  ArduinoOTA.handle();
  ArduinoOTA.setHostname("Essig_Innen");
 
  stepper.run();
 
      // Essigdosierer Stopp
    if (stepper.currentPosition() == Essigdosis) {
      Serial.println(stepper.currentPosition());
      mqttClient.publish("HH_Frischwasser/Innen/Essigdosierer", "false");      
      Serial.println("Essigdosierer gestoppt");      
      stopp();
     }
 
  // MQTT Broker
  mqttClient.loop();
  if (!mqttClient.connected()) {
    reconnectToMQTT();
  }
 
}
 
//ende loop
/////////////////////////////////////////////////////////////////////////////////

Darf man das so machen?

Es funktioniert so.

Beowolf

So sieht es jetzt aus. Habe es noch verschoben in "void Essigdosierer_deaktivieren()"

#include <ESP8266WiFi.h>
#include <ArduinoOTA.h>
#include <PubSubClient.h>
#include <AccelStepper.h>
#include <Adafruit_NeoPixel.h>

#ifndef STASSID
#define STASSID "-"
#define STAPSK  "-----"
#endif

#define MotorStatus D2 // Steppermotor aktivieren/deaktivieren
#define LEDpin D7 // Umgesteuerter GPIO für die NEO-Led
#define NUMPIXELS 1 // Anzal der LEDs

const char* ssid = STASSID;
const char* password = STAPSK;

char* mqtt_client_id = "Essig_Innen";
const char* mqtt_server = "192.168.-.-";
const int mqtt_port = -;
const char* mqtt_user = "-";
const char* mqtt_password = "-";

const byte Pegelschalter = D6;    // Pegelschalter für Essigvorrat
const byte RelaisVentil = D5;   // Relais für Wasserzufuhrventil

// const long SchritteUmdrehung = 200; // Schritte des Schrittmotors für 360 Grad der Tür
const unsigned int Essigdosis =  20000;


int lebenszeichen_zaehler = 0; // Zähler um Lebenzeichen an MQTT Broker zusenden
int lebenszeichen_interval = 10; // interval für MQTT Broker in sek
int messung_interval = 10; // interval für Pegelmessung in sek

long led_takt    = 500; // Zeittakt (ms) für die LED  ##takt##
long led_zeit; // Letzter Durchlauf (ms) für die LED  ##takt##
long lebenszeichen_takt = lebenszeichen_interval * 1000; // Zeittakt (ms)  ##takt##
long lebenszeichen_zeit; // Letzter Durchlauf (ms)  ##takt##
long lebenszeichen_ein_aus = 0; // ##takt##

long messung_takt = messung_interval *1000; // Zeittakt (ms)
long messung_zeit;  //Letzter Durchlauf (ms)


WiFiClient espClient;
PubSubClient mqttClient(espClient);

AccelStepper stepper(1, D3, D4);  //Pins für den Steppermotor STEP , DIR
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(1, LEDpin, NEO_GRB + NEO_KHZ800);

void setup() {

  pinMode(LEDpin, OUTPUT); // NEO-LED
  pinMode(Pegelschalter, INPUT_PULLUP);    // Pegelschalter für Essigtank
  pinMode(RelaisVentil, OUTPUT);   // Relais für Wasserzufuhrventil
  pinMode(MotorStatus, OUTPUT); // Enable Motor 1
  pinMode(LED_BUILTIN, OUTPUT); // Board-LED nutzen
  stepper.setMaxSpeed(1000);
  stepper.setAcceleration(1500);

  digitalWrite(MotorStatus, HIGH); //Motor deaktiviert

  Serial.begin(9600);
  //  while(!Serial){
  //    ; // wartet bis die serielle Schnittstelle eine Verbindung hergestellt hat. Wird für natives USB benötigt
  //  }

  // Per WLAN mit dem Netzwerk verbinden
  Serial.print("Verbinden mit ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  ///////////////////////////////////////////
  // Anfang Update über Wlan
  ///////////////////////////////////////////

  ArduinoOTA.onStart([]() {
    String type;
    if (ArduinoOTA.getCommand() == U_FLASH) {
      type = "sketch";
    } else { // U_FS
      type = "filesystem";
    }

    // NOTE: if updating FS this would be the place to unmount FS using FS.end()
    Serial.println("Start updating " + type);
  });
  ArduinoOTA.onEnd([]() {
    Serial.println("\nEnd");
  });
  ArduinoOTA.onProgress([](unsigned int progress, unsigned int total) {
    Serial.printf("Progress: %u%%\r", (progress / (total / 100)));
  });
  ArduinoOTA.onError([](ota_error_t error) {
    Serial.printf("Error[%u]: ", error);
    if (error == OTA_AUTH_ERROR) {
      Serial.println("Auth Failed");
    } else if (error == OTA_BEGIN_ERROR) {
      Serial.println("Begin Failed");
    } else if (error == OTA_CONNECT_ERROR) {
      Serial.println("Connect Failed");
    } else if (error == OTA_RECEIVE_ERROR) {
      Serial.println("Receive Failed");
    } else if (error == OTA_END_ERROR) {
      Serial.println("End Failed");
    }
  });
  ArduinoOTA.begin();

  ///////////////////////////////////////////
  // Ende Update über Wlan
  ///////////////////////////////////////////

  // Die IP vom Webserver auf dem seriellen Monitor ausgeben
  Serial.println("");
  Serial.println("WLAN verbunden.");
  Serial.println("IP Adresse: ");
  Serial.println(WiFi.localIP());

  // MQTT Brocker
  // Mit ioBroker Mqtt verbinden
  mqttClient.setServer(mqtt_server, mqtt_port);//MQTT Server, - Port
  mqttClient.setCallback(callback);

  // NEO_Pixel Start
  pixels.begin(); // This initializes the NeoPixel library.

  lebenszeichen_zeit = millis(); // ##takt##
  led_zeit = millis(); // ##takt##
  messung_zeit = millis();

  Serial.println("Programmanfang");
}

//ende Setup
//////////////////////////////////////////////////////////////////////////////////

void loop() {


  Pegelstand_lesen();
  Essigdosierer_deaktivieren();
  lebenszeichen();

  ArduinoOTA.handle();
  ArduinoOTA.setHostname("Essig_Innen");

  stepper.run();

  // MQTT Broker
  mqttClient.loop();
  if (!mqttClient.connected()) {
    reconnectToMQTT();
  }

}

//ende loop
/////////////////////////////////////////////////////////////////////////////////

void Pegelstand_lesen() {
   long current_time = millis();

  if (messung_zeit <= current_time) {
    if (digitalRead(Pegelschalter)) {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "1");
          } else {
      mqttClient.publish("HH_Frischwasser/Innen/Essigpegel", "0");
      }
    while (messung_zeit <= current_time)
      messung_zeit += messung_takt;
  }
}

// MQTT Funktion
// *************
void reconnectToMQTT() {

  if (mqttClient.connect(mqtt_client_id , mqtt_user, mqtt_password)) {
    Serial.println("Per MQTT mit ioBroker verbunden");

    mqttClient.publish("HH_Frischwasser/Innen/alive", "0");


    mqttClient.subscribe("HH_Frischwasser/Innen/Frischwasserventil");
    mqttClient.subscribe("HH_Frischwasser/Innen/Essigdosierer");
  } else {
    Serial.print("mqtt-Verbindung fehlgeschlagen ");
    Serial.print(mqttClient.state());
    Serial.println(" versuchen es in 5 Sekunden erneut");
    // Wait 5 seconds before retrying
    delay(5000);
  }
}


// MQTT Callback
void callback(char* topic, byte* payload, unsigned int length)
{

  payload[length] = '\0';
  String strTopic = String(topic);
  String strPayload = String((char * ) payload);

  Serial.print("Nachricht angekommen [");
  Serial.print(strTopic);
  Serial.print("----");
  Serial.print(strPayload);
  Serial.print("] ");
  Serial.println();


  if (strTopic == "HH_Frischwasser/Innen/Frischwasserventil")
  {
    // Pumpe Start
    if (strPayload == "false") {
      Serial.println("Pumpenstart über IoBroker");
      digitalWrite(RelaisVentil, HIGH);
    }

    // Pumpe Stop
    if (strPayload == "true") {
      Serial.println("Pumpenstop über IoBroker");
      digitalWrite(RelaisVentil, LOW);
    }
  }

  
  if (strTopic == "HH_Frischwasser/Innen/Essigdosierer")
  {
    // Essigdosierer Start
    if (strPayload == "true") {
      Serial.println("Start Essigdosierer über IoBroker");
      digitalWrite(MotorStatus, LOW);  //Motor aktiviert
      stepper.move(Essigdosis);
    }
  }
}

void Essigdosierer_deaktivieren() {
      // Essigdosierer Stopp
    if (stepper.currentPosition() == Essigdosis) {
      Serial.println(stepper.currentPosition());
      mqttClient.publish("HH_Frischwasser/Innen/Essigdosierer", "false");      
      Serial.println("Essigdosierer gestoppt");      
      stopp();
    }
}


void stopp() {
  stepper.setCurrentPosition(0);
  stepper.stop();
  digitalWrite(MotorStatus, HIGH); //Motor deaktiviert
}

void lebenszeichen() {
  
  // ##takt## --> 
  long current_time = millis();
  // LED auf dem Board blinken lassen
  if (led_zeit <= current_time) {
    if (digitalRead(LED_BUILTIN) == HIGH)
      digitalWrite(LED_BUILTIN, LOW);
    else
      digitalWrite(LED_BUILTIN, HIGH);
    while (led_zeit <= current_time)
      led_zeit += led_takt;
  }
  
  if (lebenszeichen_zeit <= current_time) {
    if (lebenszeichen_ein_aus == 0) {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "1");
      lebenszeichen_ein_aus = 1;
    } else {
      mqttClient.publish("HH_Frischwasser/Innen/alive", "0");
      lebenszeichen_ein_aus = 0;
    }
    while (lebenszeichen_zeit <= current_time)
      lebenszeichen_zeit += lebenszeichen_takt;
  }
  // ##takt## <-- 
}

TT-Tom

@beowolf perfekt, gut gemacht. Vielleicht jetzt noch die LED einbinden.

Community Forum

NEWS

GPIO Status Wemos d1 mini an iobroker senden

Support us

463

32.5k

81.6k

1.3m